Warping Image Objects

Object Graphics allows precise control over the color palettes used to display image objects. By initializing a palette object, both the reference image object and the transparent, warped image object can be displayed using individual color palettes.

The following example warps an African land-cover characteristics image to a political map of the continent. After displaying the images and selecting control points in each image using the XROI utility, the resulting warped image is altered to include an alpha channel, enabling transparency. Image objects are then created and displayed in an IDL Object Graphics display. Complete the following steps for a detailed description of the process.

Select the political map image. This is the reference image to which the land cover image will be warped:

mapFile= FILEPATH('afrpolitsm.png', $  
   Subdirectory = ['examples', 'data'])

Use READ_PNG routine to read in the file. Specify mapR, mapG, mapB to read in the image's associated color table:

mapImg = READ_PNG(mapFile, mapR, mapG, mapB)

Using IDLgrPalette::Init, assign the image's color table to a palette object, which will be applied to an image object in a later step:

mapPalette = OBJ_NEW('IDLgrPalette', mapR, mapG, mapB)

Select and open the land cover input image, which will be warped to the map:

landFile = FILEPATH('africavlc.png', $  
   Subdirectory = ['examples', 'data'])  
landImg = READ_PNG (landFile, landR, landG, landB)

Selecting Control Points for Image Object Warping

This section describes using the XROI utility to select corresponding control points in the two images. The arrays of control points in the input image, (Xi, Yi), will be mapped to the array of points selected in the reference image, (Xo, Yo).

Reasonably precise warping of the land classification image to the political map requires selecting numerous control points because of the irregularity of the continent's border. Select the control points in the land classification image as described in the following steps.

Load the image and its associated color table into the XROI utility, specifying the REGIONS_OUT keyword to save the region defined by the control points in the landROIout object:

XROI, landImg, landR, landG, landB, $  
   REGIONS_OUT = landROIout, /BLOCK

Select the Draw Polygon button from the XROI utility toolbar shown in the following figure. Position the crosshairs symbol over CP1, shown in the previous figure, and click the left mouse button. Repeat this action for each successive control point. After selecting the sixteenth control point, position the crosshairs over the first point selected and click the right mouse button to close the region. Your display should appear similar to the following figure.

Figure 4-13: Selecting Control Points Using XROI

Figure 4-13: Selecting Control Points Using XROI

Note
It is of no concern that portions of the continent lie outside the polygonal boundary. The EXTRAPOLATE keyword to WARP_TRI enables warping of the image areas lying outside of the boundary of control points. However, images requiring more aggressive warp models may not have good results outside of the extent of the control points when WARP_TRI is used with the /EXTRAPOLATE keyword.

Close the XROI window and assign the landROIout object data to the Xi and Yi control point vectors:

landROIout -> GetProperty, DATA = landROIdata  
Xi = landROIdata[0,*]  
Yi = landROIdata[1,*]

The following figure displays the corresponding control points to be selected in the reference image of the political map. These control points will make up the Xo and Yo arrays required by the IDL warping routines.

Figure 4-14: Control Points to be Selected in the Reference Image

Figure 4-14: Control Points to be Selected in the Reference Image

Load the image of the political map and its associated color table into the XROI utility, specifying the REGIONS_OUT keyword to save the selected region in the mapROIout object:

XROI, mapImg, mapR, mapG, mapB, $  
   REGIONS_OUT=mapROIout,/BLOCK

Select the Draw Polygon button from the XROI utility toolbar. Position the crosshairs symbol over CP1, shown in the previous figure, and click the left mouse button. Repeat this action for each successive control point. After selecting the sixteenth control point, position the crosshairs over the first point selected and click the right mouse button to close the region. Your display should appear similar to the following figure.

Figure 4-15: Selecting Control Points Using XROI

Figure 4-15: Selecting Control Points Using XROI

Close the XROI window and assign the mapROIout object data to the Xo and Yo control point vectors:

mapROIout -> GetProperty, DATA=mapROIdata  
Xo = mapROIdata[0,*]  
Yo = mapROIdata[1,*]

Warping and Displaying a Transparent Image Object

The following section describes warping the land cover image to the political map and creating image objects. The resulting warped image will then be made into a transparency by creating an alpha channel for the image. Finally, the transparent object will be displayed as an overlay to the original political map.

Warp the input image, landImg, onto the reference image using WARP_TRI. This function uses the irregular grid of the reference image, defined by Xo, Yo, as a basis for triangulation, defining the surfaces associated with (Xo, Yo, Xi) and (Xo, Yo, Yi). Each pixel in the input image is then transferred to the appropriate position in the resulting output image as designated by interpolation. Using the WARP_TRI syntax,

Result = WARP_TRI( Xo, Yo, Xi, Yi, Image 
  [, OUTPUT_SIZE=vector][, /QUINTIC] [, /EXTRAPOLATE] )

set the OUTPUT_SIZE equal to the reference image dimensions since this image forms the basis of the warped, output image. Use the EXTRAPOLATE keyword to display the portions of the image which fall outside of the boundary of selected control points:

warpImg = WARP_TRI(Xo, Yo, Xi, Yi, landImg, $  
   OUTPUT_SIZE=[600, 600], /EXTRAPOLATE)

While not required, you can quickly check the precision of the warp in a Direct Graphics display before proceeding with creating a transparency by entering the following lines:

DEVICE, DECOMPOSED = 0  
TVLCT, landR, landG, landB  
WINDOW, 3, XSIZE = 600, YSIZE = 600, $  
   TITLE = 'Image Warped with WARP_TRI'  
TV, warpImg

Precise control point selection results in accurate warping. If there is little distortion, as in the following figure, control points were successfully selected in nearly corresponding positions in both images.

Figure 4-16: Resulting Warped Image

Figure 4-16: Resulting Warped Image

A transparent image object must be a grayscale or an RGB (24-bit) image containing an alpha channel. The alpha channel controls the transparency of the pixels. See IDLgrImage::Init for more information.

The following lines convert the warped image and its associated color table into a RGB image containing four channels (red, green, blue, and alpha). First, get the dimensions of the warped image and then use BYTARR to create alphaWarp, a 4-channel by xdim by ydim array, where (xdim, ydim) are the dimensions of the warped image:

warpImgDims = SIZE(warpImg, /Dimensions)  
alphaWarp = BYTARR(4, warpImgDims[0], warpImgDims[1],$ 
   /NOZERO)

Load the red, green and blue channels of the warped land characteristics image into the first three channels of the alphaWarp array:

alphaWarp[0, *, *] = landR[warpImg]  
alphaWarp[1, *, *] = landG[warpImg]  
alphaWarp[2, *, *] = landB[warpImg]

Define the transparency of the alpha channel. First, create an array, masking out the black background of the warped image (where pixel values equal 0) by retaining only pixels with values greater than 0:

mask = (warpImg GT 0)

Apply the resulting mask to the alpha channel, the fourth channel of the array. This channel creates a 50% transparency of the pixels of the first three channels (red, green, blue) of the alphaWarp by multiplying the mask by 128B (byte). Alpha channel values range from 0 (completely transparent) to 255 (completely opaque):

alphaWarp [3, *, *] = mask*128B

Note
You can set the transparency of an entire image. To set the transparency of all pixels at 50% in this example, your could replace the two previous steps with the following two lines:
mask = BYTARR(s[0], s[1]) + 128
alphaWarp [3, *, *] = mask

Initialize the transparent image object using IDLgrImage::Init. Specify the BLEND_FUNCTION property of the image object to control how the alpha channel is interpreted. Setting the BLEND_FUNCTION to [3, 4] allows you to see through the foreground image to the background. The foreground opacity is defined by the alpha channel value, specified in the previous step:

oAlphaWarp = OBJ_NEW('IDLgrImage', alphaWarp, $  
   DIMENSIONS = [600, 600], BLEND_FUNCTION = [3, 4])

Initialize the reference image object, applying the palette created earlier:

oMapImg = OBJ_NEW('IDLgrImage', mapImg, $  
   DIMENSIONS = [600,600], PALETTE = mapPalette)

Using IDLgrWindow::Init, initialize a window object in which to display the images:

oWindow = OBJ_NEW('IDLgrWindow', DIMENSIONS = [600, 600], $  
   RETAIN = 2, TITLE = 'Overlay of Land Cover Transparency')

Create a view object using IDLgrView::Init. The VIEWPLANE_RECT keyword controls the image display in the Object Graphics window. First create an array, viewRect, which specifies the x-placement, y-placement, width, and height of the view surface. The values 0, 0 place the (0, 0) coordinate of viewing surface in the lower-left corner of the Object Graphics window:

viewRect = [0, 0, 600, 600]  
oView = OBJ_NEW('IDLgrView', VIEWPLANE_RECT = viewRect)

Using IDLgrModel::Init, initialize a model object to which the images will be applied. Add the base image and the transparent alpha image to the model:

oModel = OBJ_NEW('IDLgrModel')  
oModel -> Add, oMapImg  
oModel -> Add, oAlphaWarp

Note
Image objects appear in the Object Graphics window in the order in which they are added to the model. If a transparent object is added to the model before an opaque object, it will not be visible.

Add the model, containing the images, to the view and draw the view in the window:

oView -> Add, oModel  
oWindow -> Draw, oView

The following figure shows the warped image transparency overlaid onto the original reference image, the political map.

Figure 4-17: Object Graphics Display of the Political Map with a Transparent Land Cover Overlay

Figure 4-17: Object Graphics Display of the Political Map with a Transparent Land Cover Overlay

Use OBJ_DESTROY to clean up unneeded object references including the region objects:

OBJ_DESTROY, [oView, oMapImg, oAlphaWarp, $  
   mapPalette, landROIout, mapROIout]