PRO remove_bridges  
;  
;Read an image of New York.  
xsize = 768 ; pixels.  
ysize = 512 ; pixels.  
img = read_binary( $  
    filepath('nyny.dat', subdir=['examples', 'data']), $  
    data_dims=[xsize, ysize])  
;  
;Increase image's contrast.  
img = bytscl(img)  
;  
;Create an image mask from thresholded image.  
threshold_level = 70 ; determined empirically.  
mask = img lt threshold_level  
;  
;Make a disk-shaped "structuring element."  
disk_size = 7 ; determined empirically.  
se = shift(dist(disk_size), disk_size / 2, disk_size / 2)  
se = se le disk_size / 2  
;  
;Remove details in the mask's shape.  
mask = dilate(erode(mask, se), se)  
;  
;Fuse gaps in the mask's shape.  
mask = erode(dilate(mask, se), se)  
;  
;Remove all but the largest region in the mask.  
label_img = label_region(mask)  
labels = label_img[where(label_img ne 0)] ; Remove 
background.  
label = where(histogram(label_img) eq max(histogram(labels)))  
mask = label_img eq label[0]  
;  
;Generate a new image consisting of local area minimums.  
new_img = dilate(erode(img, se, /gray), se, /gray)  
;  
;Replace new image with original image, where not masked.  
new_img[where(mask eq 0)] = img[where(mask eq 0)]  
;  
;View result, comparing the new image with the original.  
print, 'Hit any key to end program.'   
window, xsize=xsize, ysize=ysize  
flick, img, new_img  
wdelete  
END