Previous Image Processing : Extracting and Analyzing Shapes Next

Creating Distance Maps

The MORPH_DISTANCE function computes a grayscale, N-dimensional distance map from a binary image. The map shows, for each foreground pixel, the distance to the nearest background pixel using a given norm. The norm simply defines how neighboring pixels are sampled. See the MORPH_DISTANCE description in the IDL Reference Guide for full details. The resulting values in the grayscale image denote the distance from the surveyed pixel to the nearest background pixel. The brighter the pixel, the farther it is from the background.

The following example applies the distance transformation to a grayscale image of a cultured sample of Neocosmospora vasinfecta, a common fungal plant pathogen. Complete the following steps for a detailed description of the process.


Example Code
See morphdistanceexample.pro in the examples/doc/image subdirectory of the IDL installation directory for code that duplicates this example.

  1. Prepare the display device and load a grayscale color table:
    2. DEVICE, DECOMPOSED = 0, RETAIN = 2  
LOADCT, 0

     

  2. Select and load an image:
    3. file = FILEPATH('n_vasinfecta.jpg', $  
    SUBDIRECTORY = ['examples', 'data'])  
READ_JPEG, file, img, /GRAYSCALE

     

  3. Get the size of the image and create a border for display purposes:
    4. dims = SIZE(img, /DIMENSIONS)  
padImg = REPLICATE(0B, dims[0]+10, dims[1]+10)  
padImg[5,5] = img

     

  4. Get the dimensions of the padded image, create a window and display the original image:
    5. dims = SIZE(padImg, /DIMENSIONS)  
WINDOW, 0, XSIZE = 2*dims[0], YSIZE = 2*dims[1], $  
    TITLE='Distance Map and Overlay of Binary Image'  
TVSCL, padImg, 0

     

  5. Use an intensity histogram as a guide for creating a binary image:
    6. WINDOW, 2, XSIZE = 400, YSIZE = 300  
PLOT, HISTOGRAM(padImg)

     

     


    Note
    Using an intensity histogram as a guide for determining intensity values is described in the section, Determining Intensity Values for Threshold and Stretch.

     

  6. Before using the distance transform, the grayscale image must be translated into a binary image. Create and display a binary image containing the dark tubules. Threshold the image, masking out pixels with values greater than 120:
    7. binaryImg = padImg LT 120  
WSET, 0  
TVSCL, binaryImg, 1

     

    The original image (left) and binary image (right) appear in the following figure.

     

    Figure 9-21: Original Image (left) and Binary Image (right)

    Figure 9-21: Original Image (left) and Binary Image (right)

     

  7. Compute the distance map using MORPH_DISTANCE, specifying "chessboard" neighbor sampling, which surveys each horizontal, vertical and diagonal pixel touching the pixel being surveyed, and display the result:
    8. distanceImg = MORPH_DISTANCE(binaryImg, $  
   NEIGHBOR_SAMPLING = 1)  
TVSCL, distanceImg, 2

     

  8. Display a combined image of the distance map and the binary image. Black areas within the binary image (having a value of 0) are assigned the maximum pixel value occurring in the distance image:
    9. distanceImg [WHERE (binaryImg EQ 0)] = MAX(distanceImg)  
TVSCL, distanceImg, 3

     

    The distance map (left) and resulting blended image (right) show the distance of each image element pixel from the background.

     

    Figure 9-22: Distance Map (left) and Merged Map and Binary Image (right)

    Figure 9-22: Distance Map (left) and Merged Map and Binary Image (right)

  IDL Online Help (March 06, 2007)