Previous Image Processing : Extracting and Analyzing Shapes Next

Analyzing Image Shapes

After using a morphological operation to expose the basic elements within an image, it is often useful to then extract and analyze specific information about those image elements. The following examples use the LABEL_REGION function and the CONTOUR procedure to identify and extract information about specific image objects.

The LABEL_REGION function labels all of the regions within a binary image, giving each region a unique index number. Use this function in conjunction with the HISTOGRAM function to view the population of each region. See Using LABEL_REGION to Extract Image Object Information in the following section for an example.

The CONTOUR procedure draws a contour plot from image data, and allows the selection of image objects occurring at a specific contour level. Further processing using PATH_* keywords returns the location and coordinates of polygons that define a specific contour level. See Using CONTOUR to Extract Image Object Information for an example.

Using LABEL_REGION to Extract Image Object Information

The following example identifies unique regions within the image of the Rhinosporidium seeberi parasitic protozoans and prints out region populations. Complete the following steps for a detailed description of the process.


Example Code
See labelregionexample.pro in the examples/doc/image subdirectory of the IDL installation directory for code that duplicates this example.

  1. Prepare the display device and load a grayscale color table:
    2. DEVICE, DECOMPOSED = 0, RETAIN = 2  
LOADCT, 0

     

  2. Select and open the image file:
    3. file = FILEPATH('r_seeberi.jpg', $  
    SUBDIRECTORY = ['examples','data'])  
READ_JPEG, file, image, /GRAYSCALE

     

  3. Get the image dimensions and add a border (for display purposes only):
    4. dims = SIZE(image, /DIMENSIONS)  
padImg = REPLICATE(0B, dims[0]+20, dims[1]+20)  
padImg[10,10] = image

     

  4. Get the dimensions of the padded image, create a window and display the original image:
    5. dims = SIZE(padImg, /DIMENSIONS)  
WINDOW, 0, XSIZE = 2*dims[0], YSIZE = 2*dims[1], $  
    TITLE = 'Opened, Thresholded and Labeled Region Images'  
TVSCL, padImg, 0

     

  5. Create a large, circular structuring element to extract the large circular foreground features. Define the radius of the structuring element and create the disk:
    6. radius = 5  
strucElem = SHIFT(DIST(2*radius+1), radius, radius) LE radius

     


    Tip
    Enter PRINT, strucElem to view the structure created by the previous statement.

     

  6. Apply the opening operation to the image to remove background noise and display the image:
    7. openImg = MORPH_OPEN(padImg, strucElem, /GRAY)  
TVSCL, openImg, 1

     

    This original image (left) and opened image (right) appear in the following figure.

     

    Figure 9-28: Original Image (left) and Application of Opening Operator (right)

    Figure 9-28: Original Image (left) and Application of Opening Operator (right)

     

  7. Display an intensity histogram to use as a guide when thresholding:
    8. WINDOW, 2, XSIZE = 400, YSIZE = 300  
PLOT, HISTOGRAM(openImg)

     

     


    Note
    Using an intensity histogram as a guide for determining threshold values is described in the section, Determining Intensity Values for Threshold and Stretch.

     

  8. Retain only the brighter, foreground pixels by setting the threshold intensity at 170 and display the binary image:
    9. threshImg = openImg GE 170  
WSET, 0  
TVSCL, threshImg, 2

     

  9. Identify unique regions using the LABEL_REGION function:
    10. regions = LABEL_REGION(threshImg)

     

  10. Use the HISTOGRAM function to calculate the number of elements in each region: 
    11. hist = HISTOGRAM(regions)

     

  11. Create a FOR loop that will return the population and percentage of each foreground region based on the results returned by the HISTOGRAM function:
    12. FOR i=1, N_ELEMENTS (hist) - 1 DO PRINT, 'Region', i, $  
   ', Pixel Popluation = ', hist(i), $  
   '   Percent = ', 100.*FLOAT(hist[i])/(dims[0]*dims[1])

     

  12. Load a color table and display the regions. For this example, use the sixteen level color table to more easily distinguish individual regions: 
    13. LOADCT, 12  
TVSCL, regions, 3

     

    In the following figure, the image containing the labeled regions (right) shows 19 distinct foreground regions.

     

    Figure 9-29: Binary Image (left) and Image of Unique Regions (right)

    Figure 9-29: Binary Image (left) and Image of Unique Regions (right)

     


    Tip
    Display the color table by entering XLOADCT at the command line. By viewing the color table, you can see that region index values start in the lower-left corner of the image. Realizing this makes it easier to relate the region populations printed in the Output Log with the regions shown in the image.

     

  13. Create a new window and display the individual region populations by graphing the values of hist using the SURFACE procedure: 
    14. WINDOW, 1, $  
   TITLE = 'Surface Representation of Region Populations'  
FOR i = 1, N_ELEMENTS(hist)-1 DO $  
   regions[WHERE(regions EQ i)] = hist[i]  
SURFACE, regions

     

    The previous command results in the following display of the region populations.

     

    Figure 9-30: Surface Representation of Region Populations

    Figure 9-30: Surface Representation of Region Populations

Using CONTOUR to Extract Image Object Information

It is possible to extract information about an image feature using the CONTOUR procedure. The following example illustrates how to select an image feature and return the area of that feature, in this case, calculating the size of a gas pocket in a CT scan of the thoracic cavity. Complete the following steps for a detailed description of the process.


Example Code
See extractcontourinfo.pro in the examples/doc/image subdirectory of the IDL installation directory for code that duplicates this example.


Note
For more information on computing statistics for defined image objects see Working with Regions of Interest (ROIs)

  1. Prepare the display device and load a color table:
    2. DEVICE, DECOMPOSED = 0, RETAIN = 2  
LOADCT, 5

     

  2. Determine the path to the file:
    3. file = FILEPATH('ctscan.dat', $  
   SUBDIRECTORY = ['examples', 'data'])

     

  3. Initialize the size parameters:
    4. dims = [256, 256]

     

  4. Import the image from the file:
    5. image = READ_BINARY(file, DATA_DIMS = dims)

     

  5. Create a window and display the image:
    6. WINDOW, 0, XSIZE = dims[0], YSIZE = dims[1]  
TVSCL, image

     

  6. Create another window and use CONTOUR to display a filled contour of the image, specifying 255 contour levels which correspond to the number of values occurring in byte data: 
    7. WINDOW, 2  
CONTOUR, image, /XSTYLE, /YSTYLE, NLEVELS = 255, $  
   /FILL

     

     


    Note
    Replace NLEVELS = 255 with NLEVELS = MAX(image) if your display uses less than 256 colors.

     

  7. Use the PATH_* keywords to obtain information about the contours occurring at level 40: 
    8. CONTOUR, image, /XSTYLE, /YSTYLE, LEVELS = 40, $  
   PATH_INFO = info, PATH_XY = xy, /PATH_DATA_COORDS

     

    The PATH_INFO variable, info, contains information about the paths of the contours, which when used in conjunction with PATH_XY, traces closed contour paths. Specify PATH_DATA_COORDS when using PATH_XY if you want the contour positions to be measured in data units instead of the default normalized units.

     

  8. Using the coordinate information obtained in the previous step, use the PLOTS procedure to draw the contours of image objects occurring at level 40, using a different line style for each contour: 
    9. FOR i = 0, (N_ELEMENTS(info) - 1) DO PLOTS, $  
   xy[*, info[i].offset:(info[i].offset + info[i].n - 1)], $  
   LINESTYLE = (i < 5), /DATA

     

  9. The specified contour is drawn with a dashed line or LINESTYLE number 2 (determined by looking at "Graphics Keywords" in Appendix B of the IDL Reference Guide). Use REFORM to create vectors containing the x and y boundary coordinates of the contour:
    10. x = REFORM(xy[0, info[2].offset:(info[2].offset + $  
   info[2].n - 1)])  
y = REFORM(xy[1, info[2].offset:(info[2].offset + $  
   info[2].n - 1)])

     

  10. Set the last element of the coordinate vectors equal to the first element to ensure that the contour area is completely enclosed:
    11. x = [x, x[0]]  
y = [y, y[0]]

     

  11. This example obtains information about the left-most gas pocket. For display purposes only, draw an arrow pointing to the region of interest:
    12. ARROW, 10, 10, (MIN(x) + MAX(x))/2, COLOR = 180, $  
   (MIN(y) + MAX(y))/2, THICK = 2, /DATA

     

    The gas pocket is indicated with an arrow as shown in the following figure.

     

    Figure 9-31: Gas Pocket Indicated in CT Scan of Thoracic Cavity

    Figure 9-31: Gas Pocket Indicated in CT Scan of Thoracic Cavity

     

  12. Output the resulting coordinate vectors, using TRANSPOSE to print vertical lists of the coordinates:
    13. PRINT, ''  
PRINT, '       x       ,       y'  
PRINT, [TRANSPOSE(x), TRANSPOSE(y)], FORMAT = '(2F15.6)'

     

    The FORMAT statement tells IDL to format two 15 character floating point values that have 6 characters following the decimal of each value.

     

  13. Use the POLY_AREA function to compute the area of the polygon created by the x and y coordinates and print the result:
    14. area = POLY_AREA(x, y)  
PRINT, 'area = ', ROUND(area), '  square pixels'

     

    The result, 121 square pixels, appears in the Output Log.

     

  IDL Online Help (March 06, 2007)